// SPHERE by : Menasoft ©1997-2006
// www.sphereserver.net
// All SPHERE script files and formats are copyright Menasoft & Partners.
// This file may be freely edited for personal use, but may not be distributed
// in whole or in part, in any format without express written permission from
// Menasoft & Partners.  All donations and contributions
// become the property of Menasoft & Partners.
//****************************************************************************
// FILE LAST UPDATED: Tuesday, December 6, 2005
//
//VERSION=0.56b
VERSION=0.55i

[ITEMDEF 02252]
defname=i_spellbook_paladin
//type=t_spellbook_pala
type=t_spellbook
name=Paladin Spellbook
weight=1
resources=80 i_parchment,1 i_hide, 1 i_cloth
layer=1

ON=@Create
	ATTR=attr_magic|attr_newbie
	CATEGORY=Provisions - Alchemy & Magic
	SUBSECTION=Paladin
	DESCRIPTION=Paladin Spellbook

[ITEMDEF 0238c]
defname=i_spellbook_bushido
//type=t_spellbook_bushido
type=t_spellbook
name=Book of Bushido
weight=1
resources=80 i_parchment,1 i_hide, 1 i_cloth
layer=1

ON=@Create
	ATTR=attr_magic|attr_newbie
	CATEGORY=Provisions - Alchemy & Magic
	SUBSECTION=Bushido
	DESCRIPTION=Bushido Spellbook
	
[ITEMDEF 023a0]
defname=i_spellbook_ninjitsu
//type=t_spellbook_ninjitsu
type=t_spellbook
name=Book of Ninjitsu
weight=1
resources=80 i_parchment,1 i_hide, 1 i_cloth
layer=1

ON=@Create
	ATTR=attr_magic|attr_newbie
	CATEGORY=Provisions - Alchemy & Magic
	SUBSECTION=Ninjitsu
	DESCRIPTION=Ninjitsu Spellbook
	
[ITEMDEF 02d50]
defname=i_spellbook_arcanist
//type=t_spellbook_arcanist
type=t_spellbook
name=Book of Arcanist
weight=1
resources=80 i_parchment,1 i_hide, 1 i_cloth
layer=1

ON=@Create
	ATTR=attr_magic|attr_newbie
	CATEGORY=Provisions - Alchemy & Magic
	SUBSECTION=Arcanist
	DESCRIPTION=Arcanist Spellbook
	
[ITEMDEF 02251]
DEFNAME=i_daemon_skull
NAME=Daemon Skull
TYPE=t_normal
VALUE=5000

[ITEMDEF 02231]
DEFNAME=i_giant_mush
NAME=Giant Mushroom
TYPE=t_normal

[ITEMDEF 02232]
DEFNAME=i_ant_hill
NAME=Ant Hill
TYPE=t_normal

[ITEMDEF 02328]
DEFNAME=i_snowman
NAME=Snow Man
TYPE=t_normal

[ITEMDEF 0232a]
DEFNAME=i_giftbox
NAME=Gift Box
TYPE=t_normal

[ITEMDEF i_gem_arcane]
ID=i_worldgem_lg
TYPE=T_EQ_SCRIPT
VALUE=5000
CATEGORY=Provisions - Jewels and Jewelry
SUBSECTION=Special Jewels
DESCRIPTION=Arcane Gem

ON=@DCLICK
	TARGET Select the item you wish to enchant
	RETURN 1

ON=@TARGON_ITEM
	IF (<SRC.TARG.ID>==01f03)||(<SRC.TARG.ID>==01515)||(<SRC.TARG.ID>==01711)||(<SRC.TARG.ID>==013c6)
		IF (<SRC.TARG.TOPOBJ.UID>==<SRC.UID>)
			IF (<SRC.TARG.QUALITY> > 176)
				IF !(<SRC.TARG.ATTR>&(attr_magic|attr_newbie))
					SRC.EMOTE enchant the <SRC.TARG.NAME>
					SRC.SOUND snd_SPELL_PROTECTION
					IF (<SRC.TARG.ID>==01f03)
						SRC.NEWITEM i_robe_arcane
						SRC.ACT.QUALITY={177 200}
					elif (<SRC.TARG.ID>==01515)
						SRC.NEWITEM i_cape_arcane
						SRC.ACT.QUALITY={177 200}
					elif (<SRC.TARG.ID>==01711)
						SRC.NEWITEM i_boots_thigh_arcane
						SRC.ACT.QUALITY={177 200}
					elif (<SRC.TARG.ID>==013c6)
						SRC.NEWITEM i_leather_gloves_arcane
						SRC.ACT.QUALITY={177 200}
					ELSE
						SERV.LOG Logic error in i_gem_arcane
					endif
					SRC.ACT.NAME=<SRC.ACT.NAME> crafted by <SRC.NAME>
					SRC.ACT.ATTR=021
					SRC.ACT.BOUNCE
					SRC.TARG.REMOVE
					REMOVE
				ELSE
					SRC.SYSMESSAGE @021 That clothing is already enchanted
				endif
			ELSE
				SRC.SYSMESSAGE @021 The clothing you wish to enchant must be exceptional
			endif
		ELSE
			SRC.SYSMESSAGE @021 The clothing you wish to enchant must be in your backpack
		endif
	elif (<SRC.TARG.ID>==026ad)||(<SRC.TARG.ID>==026ae)||(<SRC.TARG.ID>==026af)||(<SRC.TARG.ID>==026b0)
		SRC.EMOTE recharge <SRC.TARG.NAME>
		SRC.TARG.MORE2=<SRC.TARG.MORE2> + <EVAL <SRC.TAILORING>/50>
		IF (<SRC.TARG.MORE2>>24)
			SRC.TARG.MORE2=24
		endif
		SRC.SYSMESSAGE @030 The <SRC.TARG.NAME> now has <EVAL <SRC.TARG.MORE2>> charges
	ELSE
		SRC.SYSMESSAGE @021 You can not enchant that item with this gem
	endif
	RETURN 1

[EVENTS e_arcane_clothing]

ON=@SPELLCAST
	// This event does nothing since @SPELLCAST is not called if the caster
	// has no regs ... sigh
	IF (<CANCAST <ARGN>>==0)
		SYSMESSAGE You can not cast this spell ... but the Arcane robe uses a charge to help you!
		TRY CAST <ARGN>
	endif
	RETURN 1

[FUNCTION f_arcane_equip]
IF (<MORE2> > 0)
	SRC.EVENTS +e_arcane_clothing
	SRC.SOUND=0fd
	SRC.EFFECT=3,i_fx_bless_effect,6,16,0
endif

[FUNCTION f_arcane_unequip]
var.KeepEvent=0
IF (<ARGN>=026ad)
	IF (<SRC.FINDLAYER(22).ID>==026ae)&&(<SRC.FINDLAYER(22).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(3).ID>==026af)&&(<SRC.FINDLAYER(3).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(7).ID>==026b0)&&(<SRC.FINDLAYER(7).MORE2>>0)
		var.KeepEvent=1
	ELSE
		var.KeepEvent=0
	endif
elif (<ARGN>=026ae)
	IF (<SRC.FINDLAYER(20).ID>==026ad)&&(<SRC.FINDLAYER(20).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(3).ID>==026af)&&(<SRC.FINDLAYER(3).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(7).ID>==026b0)&&(<SRC.FINDLAYER(7).MORE2>>0)
		var.KeepEvent=1
	ELSE
		var.KeepEvent=0
	endif
elif (<ARGN>=026af)
	IF (<SRC.FINDLAYER(20).ID>==026ad)&&(<SRC.FINDLAYER(20).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(22).ID>==026ae)&&(<SRC.FINDLAYER(22).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(7).ID>==026b0)&&(<SRC.FINDLAYER(7).MORE2>>0)
		var.KeepEvent=1
	ELSE
		var.KeepEvent=0
	endif
elif (<ARGN>=026b0)
	IF (<SRC.FINDLAYER(20).ID>==026ad)&&(<SRC.FINDLAYER(20).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(22).ID>==026ae)&&(<SRC.FINDLAYER(22).MORE2>>0)
		var.KeepEvent=1
	elif (<SRC.FINDLAYER(3).ID>==026af)&&(<SRC.FINDLAYER(3).MORE2>>0)
		var.KeepEvent=1
	ELSE
		var.KeepEvent=0
	endif
ELSE
	SERV.LOG logic error in f_arcane_unequip
endif
IF (<var.KeepEvent>==0)
	SRC.EVENTS -e_arcane_clothing
	SRC.SOUND=0fd
endif

[ITEMDEF 026ad]
DEFNAME=i_cape_arcane
NAME=Arcane Cloak
TYPE=t_clothing
REQSTR=16
WEIGHT=5
DYE=1
ARMOR=5
RESOURCES=14 i_cloth, 1 i_thread, 1 i_gem_arcane
SKILLMAKE=TAILORING 45.4, t_sewing_kit
CATEGORY=Provisions - Clothes
SUBSECTION=Magic
DESCRIPTION=Arcane Cloak

ON=@CREATE
	HITPOINTS={50 100}
	MORE2=24

ON=@EQUIP
	f_arcane_equip

ON=@UNEQUIP
	f_arcane_unequip 026ad

ON=@CLIENTTOOLTIP
	SRC.ADDCLILOC 1060728,<EVAL <MORE2>>,24

[ITEMDEF 026ae]
DEFNAME=i_robe_arcane
NAME=Arcane Robe
TYPE=t_clothing
REQSTR=32
WEIGHT=3
DYE=1
ARMOR=7
RESOURCES=16 i_cloth, 1 i_thread, 1 i_gem_arcane
SKILLMAKE=TAILORING 59.0, t_sewing_kit
CATEGORY=Provisions - Clothes
SUBSECTION=Magic
DESCRIPTION=Arcane Robe

ON=@CREATE
	HITPOINTS={50 100}
	MORE2=24

ON=@EQUIP
	f_arcane_equip

ON=@UNEQUIP
	f_arcane_unequip 026ae

ON=@CLIENTTOOLTIP
	SRC.ADDCLILOC 1060728,<EVAL <MORE2>>,24

[ITEMDEF 026af]
DEFNAME=i_boots_thigh_arcane
NAME=Arcane Thigh Boots
TYPE=T_CLOTHING
REQSTR=8
WEIGHT=5
DYE=1
ARMOR=6
RESOURCES=10 i_hides_cut, 1 i_thread, 1 i_gem_arcane
SKILLMAKE=TAILORING 25.0, t_sewing_kit
CATEGORY=Provisions - Clothes
SUBSECTION=Magic
DESCRIPTION=Arcane Thigh Boots

ON=@CREATE
	HITPOINTS={50 100}
	MORE2=24

ON=@EQUIP
	f_arcane_equip

ON=@UNEQUIP
	f_arcane_unequip 026af

ON=@CLIENTTOOLTIP
	SRC.ADDCLILOC 1060728,<EVAL <MORE2>>,24

[ITEMDEF 026b0]
DEFNAME=i_leather_gloves_arcane
NAME=Arcane Leather Gloves
TYPE=t_armor_leather
REQSTR=8
WEIGHT=1
DYE=1
ARMOR=13
REQSTR=10
RESOURCES=3 i_hides_cut, 1 i_gem_arcane
SKILLMAKE=TAILORING 56.8, t_sewing_kit
CATEGORY=Provisions - Armor
SUBSECTION=Magic
DESCRIPTION=Arcane Leather Gloves

ON=@CREATE
	HITPOINTS={50 100}
	MORE2=24

ON=@EQUIP
	f_arcane_equip

ON=@UNEQUIP
	f_arcane_unequip 026b0

ON=@CLIENTTOOLTIP
	SRC.ADDCLILOC 1060728,<EVAL <MORE2>>,24

[ITEMDEF 0232f]
DEFNAME=i_snowflake
NAME=Snow Flake
TYPE=t_normal

[ITEMDEF 02313]
DEFNAME=i_mini_tower1
NAME=Mini House
TYPE=t_normal

[ITEMDEF 02206]
DEFNAME=i_crystal_1
NAME=Crystal
TYPE=t_wall
CAN=CAN_I_BLOCK

[ITEMDEF 026ba]
DEFNAME=i_scythe
//NAME=Scythe
TYPE=t_weapon_sword
RESOURCES=18 i_ingot_iron
REQSTR=40
WEIGHT=10
TWOHANDS=Y

TYPE=T_WEAPON_SWORD
FLIP=1
DAM=8,40
//SPEED=30
SKILL=Swordsmanship
CATEGORY=Provisions - Weapons
SUBSECTION=Polearms
DESCRIPTION=Scythe
SKILLMAKE=BLACKSMITHING 50.0
DUPELIST=026c4

ON=@Create
HITPOINTS={31 100}

[ITEMDEF 026c4]
DUPEITEM=026ba

[ITEMDEF i_scythe_soul_reaver]
ID=i_scythe
NAME=Soul Reaver

ON=@Create
NAME=The Soul Reaver	//There's only one.
COLOR=0497
HITPOINTS={31 100}

ON=@Equip
MOREY=<EVAL (<SRC.HERDING>+<SRC.SWORDSMANSHIP>+<SRC.TACTICS>) / 3>

ON=@Damage
SRC.EVENTS=+e_damagedrain
SRC.WOUND <EVAL {5 <EVAL <MOREY>/40>}>

[FUNCTION wound]
IF (<FINDID.i_memory_wounding>)
	FINDID.i_memory_wounding.MORE1=<EVAL <ARGN>>
	FINDID.i_memory_wounding.TIMERd=3
	RETURN 0
ENDIF

VAR.OLDACT=<EVAL <ACT.UID>>
NEWITEM i_memory_wounding
ACT.MORE1=<EVAL <ARGN>>
ACT.TIMERd=3
EQUIP <ACT.UID>
ACT=<EVAL <VAR.OLDACT>>
VAR.OLDACT=

[ITEMDEF i_memory_wounding]
ID=i_memory
TYPE=t_eq_script
NAME=Wounding memory

ON=@Create
ATTR=attr_move_never|attr_invis

ON=@Equip
SRC.SYSMESSAGE You were wounded! You will temporarily lose HP gradually.

ON=@Unequip
SRC.SYSMESSAGE You are no longer wounded.

ON=@Timer
IF ((<MORE1>==0)||(<CONT.HITS> <= 0))
	REMOVE
ELSE
	MORE1=<EVAL <MORE1>+(-1)>
	CONT.HITS=<EVAL <CONT.HITS>+(-1)>
	VAR.OLDACT=<EVAL <CONT.ACT.UID>>
	CONT.NEWITEM <HVAL {0122a 0122f}>	//Blood.
	CONT.ACT.ATTR=attr_decay
	CONT.ACT.COLOR=<CONT.BLOODCOLOR>
	CONT.ACT.P=<CONT.P>
	CONT.ACT.TIMER=<EVAL {1 5}>
	CONT.ACT=<EVAL <VAR.OLDACT>>
	CONT.UPDATE
	VAR.OLDACT=
	TIMERd=3
ENDIF

RETURN 1

[ITEMDEF 026bb]
DEFNAME=i_sickle
NAME=Sickle
TYPE=t_weapon_sword

RESOURCES=8 i_ingot_iron
WEIGHT=5
FLIP=1
DAM=6,18
//SPEED=50
SKILL=Swordsmanship
REQSTR=10
TWOHANDS=N
CATEGORY=Provisions - Weapons
SUBSECTION=Knives & Daggers
DESCRIPTION=Sickle
DUPELIST=026c5
SKILLMAKE=BLACKSMITHING 62.0
RESOURCES2=10 i_ingot_iron

ON=@Create
HITPOINTS={31 90}

[ITEMDEF 026c5]
//Sickle
DUPEITEM=026bb

[ITEMDEF i_sickle_druid]
ID=i_sickle
NAME=Druid's Sickle

ON=@Create
COLOR=059b
HITPOINTS={101 140}
MOREY={0.0 100.0}

ON=@Equip

SRC.CAMPING=<EVAL <SRC.CAMPING>+40.0>
IF !(<SRC.ISGM>)
	SRC.CARTOGRAPHY=<EVAL <SRC.CARTOGRAPHY>+10.0>
	SRC.LUMBERJACKING=<EVAL <SRC.LUMBERJACKING>+30.0>
	SRC.CARPENTRY=<EVAL <SRC.CARPENTRY>+30.0>
	SRC.COOKING=<EVAL <SRC.COOKING>+20.0>
	SRC.FISHING=<EVAL <SRC.FISHING>+20.0>
	SRC.HIDING=<EVAL <SRC.HIDING>+60.0>
	SRC.STEALTH=<EVAL <SRC.STEALTH>+60.0>
	SRC.DETECTINGHIDDEN=<EVAL <SRC.DETECTINGHIDDEN>+60.0>
	SRC.TRACKING=<EVAL <SRC.TRACKING>+50.0>
	SRC.TAMING=<EVAL <SRC.TAMING>+60.0>
	SRC.ANIMALLORE=<EVAL <SRC.ANIMALLORE>+80.0>
ENDIF

LINK=04004bef7
DOSWITCH <EVAL <LINK.TAG.SEASON>>
	COLOR=059b	
	COLOR=02e7
	COLOR=05dd
	COLOR=0
ENDDO

DOSWITCH <EVAL <LINK.TAG.SEASON>>
	SRC.SFX 1
	SRC.SFX 13
	SRC.SFX 41
	SRC.SFX 20
ENDDO

LINK=

ON=@Unequip
SRC.CAMPING=<EVAL <SRC.CAMPING>+(-40.0)>
IF !(<SRC.ISGM>)
	SRC.CARTOGRAPHY=<EVAL <SRC.CARTOGRAPHY>+(-10.0)>
	SRC.LUMBERJACKING=<EVAL <SRC.LUMBERJACKING>+(-30.0)>
	SRC.CARPENTRY=<EVAL <SRC.CARPENTRY>+(-30.0)>
	SRC.COOKING=<EVAL <SRC.COOKING>+(-20.0)>
	SRC.FISHING=<EVAL <SRC.FISHING>+(-20.0)>
	SRC.HIDING=<EVAL <SRC.HIDING>+(-60.0)>
	SRC.STEALTH=<EVAL <SRC.STEALTH>+(-60.0)>
	SRC.DETECTINGHIDDEN=<EVAL <SRC.DETECTINGHIDDEN>+(-60.0)>
	SRC.TRACKING=<EVAL <SRC.TRACKING>+(-50.0)>
	SRC.TAMING=<EVAL <SRC.TAMING>+(-60.0)>
	SRC.ANIMALLORE=<EVAL <SRC.ANIMALLORE>+(-80.0)>
ENDIF

COLOR=059b

ON=@Click
IF (<EVAL 0<SRC.TAG.DRUIDSHAPESHIFT>> > 0)
	SRC.TAG.DRUIDSHAPESHIFT=
	SRC.BODY=<SRC.OBODY>
	SRC.COLOR=<SRC.OSKIN>
	SRC.KARMA=<EVAL <SRC.TAG.OLDKARMA>>
	SRC.TAG.OLDKARMA=
	SRC.NAME=<SRC.TAG.OLDNAME>
	SRC.TAG.OLDNAME=
ENDIF

ON=@Dclick
IF (<EVAL 0<SRC.TAG.CHOOSESHAPE>> > 0)
	TARGET Choose a pet to shapeshift into.
	RETURN 1
ENDIF

ON=@Targon_Char
IF (<SRC.UID>==<SRC.TARG.UID>)
	IF (<EVAL 0<SRC.TAG.CHOOSESHAPE>> > 0)
		SRC.TAG.CHOOSESHAPE=
		SRC.SYSMESSAGE Shapeshifting cancelled.
	ELSE
		SRC.TAG.CHOOSESHAPE=1
		TARGET Choose a pet to shapeshift into.
	ENDIF

	RETURN 1
ENDIF

IF (<SRC.TARG.ISMYPET>)
	IF (<EVAL 0<SRC.TAG.CHOOSESHAPE>> > 0)
		SRC.BODY=<SRC.TARG.BODY>
		SRC.TAG.OLDNAME=<SRC.NAME>
		SRC.NAME=<SRC.TARG.NAME>
		SRC.COLOR=<SRC.TARG.COLOR>
		SRC.TAG.OLDKARMA=<SRC.KARMA>
		SRC.KARMA=<SRC.TARG.KARMA>
		SRC.TAG.DRUIDSHAPESHIFT=1
		SRC.RESEND
		SRC.TAG.CHOOSESHAPE=
		RETURN 1
	ELSE
		SRC.NEWITEM=<SRC.TARG.ICON> 
		SRC.ACT.NAME=<SRC.TARG.NAME> 
		SRC.ACT.COLOR=<SRC.TARG.COLOR> 
		SRC.ACT.MORE1=<SRC.TARG.ID> 
		SRC.ACT.BOUNCE 
		SRC.TARG.REMOVE 
		RETURN 1 
	ENDIF
ELSEIF ((<SRC.TARG.NPC> == brain_animal)&&(!<SRC.TARG.MEMORYFINDTYPE.memory_ipet>))
	SRC.TARG.MESSAGE It seems to accept you as master.
	SRC.TARG.TAME 1
	RETURN 1
ENDIF

ON=@Targon_Item
IF (<SRC.TARG.TYPE>==t_figurine)
	SRC.NEWDUPE <SRC.TARG.UID>
	SRC.ACT.BOUNCE
	RETURN 1
ENDIF

IF ((<SRC.TARG.TYPE>==t_log)&&(<SRC.RESTEST 10 t_log>))
	SRC.SYSMESSAGE You enchant the logs.
	SRC.CONSUME 10 t_log
	SRC.NEWITEM i_log_enchanted
	SRC.ACT.BOUNCE
ENDIF

IF ((<SRC.TARG.TYPE>==t_yarn)&&(<SRC.RESTEST 10 t_yarn>))
	SRC.SYSMESSAGE You enchant the yarn.
	SRC.CONSUME 10 t_yarn
	SRC.NEWITEM i_yarn_enchanted
	SRC.ACT.BOUNCE
ENDIF

IF (<SRC.TARG.TYPE>==t_druidplant)
	SRC.NEWITEM i_moongate_blue
	SRC.ACT.P=<SRC.P>
	SRC.ACT.MOREP=<SRC.TARG.MOREP>
	SRC.ACT.TIMER=60
	SRC.ACT.ATTR=attr_move_never|attr_decay
	SRC.ACT.UPDATE
	SRC.SFX snd_SPELL_GATE_TRAVEL
ENDIF

IF (<SRC.TARG.TYPE>==t_weapon_arrow)
	SRC.SKILLMENU sm_enchant_arrows
	RETURN 1
ENDIF

IF (<SRC.TARG.TYPE>==t_new_arrow)
	SRC.SYSMESSAGE You disenchant the arrows.
	SRC.NEWITEM i_arrow
	SRC.ACT.AMOUNT <SRC.TARG.AMOUNT>
	SRC.ACT.BOUNCE
	SRC.TARG.REMOVE
	RETURN 1
ENDIF

ON=@Damage
CONT.HITS=<EVAL <CONT.HITS>+<ARGN>>

[ITEMDEF 026c2]
DEFNAME=i_bow_composite
TYPE=T_WEAPON_BOW
FLIP=1
SKILLMAKE=37.8 BOWCRAFT
RESOURCES=14 I_LOG
RESOURCES2=14 I_LOG, i_cat_gut
WEIGHT=7
DAM=11,30
//SPEED=20
SKILL=Archery
REQSTR=70
TWOHANDS=Y
CATEGORY=Provisions - Weapons
SUBSECTION=Bows
DESCRIPTION=Composite Bow
DUPELIST=026cc

TDATA3=i_arrow
TDATA4=i_arrow_x

ON=@Create
HITPOINTS={31 60}

[ITEMDEF 026cc]
DUPEITEM=026cc

[ITEMDEF 026bc]
DEFNAME=i_scepter
TYPE=t_wand
FLIP=1
WEIGHT=8
DAM=6,20
SKILL=Mace Fighting
REQSTR=40
TWOHANDS=Y
DUPELIST=026c6
RESOURCES=8 i_ingot_iron, 1 i_bone_helmet
VALUE=1200
SKILLMAKE=BLACKSMITHING 80.0

ON=@Create
ATTR=attr_magic
HITPOINTS={35 110}

ON=@Equip
MOREY=<SRC.MAGERY>

ON=@SpellEffect
IF (<MORE2> >= 50)
	SRC.SYSMESSAGE Scepters cannot have more than 50 charges.
	RETURN 1
ENDIF

IF !(<ATTR> & attr_magic)
	ATTR=<ATTR>|attr_magic
ENDIF

IF ((<MOREX>==0)||(<MORE2>==0))
	MOREX=<ARGN>
ENDIF

IF (<ARGN>==<MOREX>)
	MORE2=<EVAL <MORE2>+1>
ELSE
	SRC.SYSMESSAGE This scepter does not carry that spell.
ENDIF

RETURN 1

ON=@Damage
//If charged with dispel, scepters are a bit special.
IF ((<SRC.FLAGS>&statf_conjured)&&((<MOREX>==41)||(<MOREX>==54))&&(<MORE2> > 0))
	EMOTE expends a charge and banishes the summoned creature.
	MORE2=<EVAL <MORE2> +(-1)>
	SRC.SPELLEFFECT <MOREX>, <MOREY>
ENDIF

[ITEMDEF 026c6]
DUPEITEM=026bc

[ITEMDEF i_scepter_magebane]
NAME=Scepter of Mage's Bane
ID=i_scepter
TYPE=t_wand

ON=@Create
ATTR=attr_magic
MOREX=s_mana_drain
MOREY=50.0
MORE2=10
HITPOINTS={35 110}

ON=@Equip
SRC.SYSMESSAGE The scepter feeds off of your mana and hinders your magical abilities.
MOREY=<EVAL <SRC.MANA>*10>
SRC.MANA=0

IF (<SRC.MAGERY> >= 15.0)
	SRC.MAGERY=<EVAL <SRC.MAGERY>+(-15.0)>
ELSE
	SRC.TAG.MAGERYDIFF=<SRC.MAGERY>
	SRC.MAGERY=0.0
ENDIF

ON=@Unequip
SRC.SYSMESSAGE Your magical ability is restored.
IF (<EVAL 0<SRC.TAG.MAGERYDIFF>> > 0)
	SRC.MAGERY=<EVAL <SRC.MAGERY>+<SRC.TAG.MAGERYDIFF>>
	SRC.TAG.MAGERYDIFF=
ELSE
	SRC.MAGERY=<EVAL <SRC.MAGERY>+15.0>
ENDIF

ON=@Damage
IF (<SRC.MANA> <= <EVAL 2*<ARGN1>>)
	SRC.MANA=0
ELSE
	SRC.MANA=<EVAL <SRC.MANA>+(-2*<ARGN1>)>
ENDIF

CONT.SYSMESSAGE You deal <EVAL 2*<ARGN1>> points of mana damage to <SRC.NAME>.

[TYPEDEF t_druidplant]
DEFNAME=t_druidplant

//ON=@Timer
//IF (<MORE1>==1)
//	DISPID=<ID>
//	MORE1=0
//	UPDATE
//	RETURN 1
//ENDIF

//ON=@Step
//IF (<MORE1>==1)
//	SRC.GO <MOREP>
//ENDIF

[SKILLMENU sm_enchant_arrows]
Enchant Arrows
ON=i_arrow_silver <name>
TARG.ID=i_arrow_silver
TARG.COLOR=color_o_silver
TARG.MORE2=65.0

ON=i_arrow_poison <name>
TARG.ID=i_arrow_poison
TARG.COLOR=color_o_verite
TARG.MORE2=70.0

ON=i_arrow_ice <name>
TARG.ID=i_arrow_ice
TARG.COLOR=color_o_mytheril
TARG.MORE2=85.0

ON=i_arrow_blunt <name>
TARG.ID=i_arrow_blunt
TARG.COLOR=1001
TARG.MORE2=50.0

ON=i_arrow_fire <name>
TARG.ID=i_arrow_fire
TARG.COLOR=021
TARG.MORE2=100.0

ON=i_arrow_darkness <name>
TARG.ID=i_arrow_darkness
TARG.COLOR=color_o_blackrock
TARG.MORE2=100.0

ON=i_arrow_light <name>
TARG.ID=i_arrow_light
TARG.COLOR=color_o_gold
TARG.MORE2=100.0