[DEFNAME shipfix]
hidenuketoggle	1	// 1 Enables 'HideNuke' any other number ( preferablly 0 ) disables 'HideNuke'

[FUNCTION hidenuke]
IF (<ARGN> <= 29)
	SRC.SYSMESSAGE 
	HIDENUKE <EVAL <ARGN>+1>
ENDIF

[ITEMDEF i_nuke_node]
ID=i_corpse
TYPE=t_script
NAME=Place Holder

ON=@Create
	AMOUNT=424
	ATTR=attr_static|attr_decay
	TIMER=0

ON=@Click
	RETURN 1

[FUNCTION shipfix]
// Small Ships
IF (<BASEID> == i_multi_ship_small_n) || (<BASEID> == i_multi_ship_dragon_small_n)
	TRY VAR.<UID>HATCH 0 -4 0
	TRY VAR.<UID>TILLERMAN 1 4 0
	TRY VAR.<UID>LEFTSIDE -2 0 0
	TRY VAR.<UID>RIGHTSIDE 2 0 0
ELIF (<BASEID> == i_multi_ship_small_w) || (<BASEID> == i_multi_ship_dragon_small_w)
	TRY VAR.<UID>HATCH -4 0 0
	TRY VAR.<UID>TILLERMAN 4 0 0
	TRY VAR.<UID>LEFTSIDE 0 2 0
	TRY VAR.<UID>RIGHTSIDE 0 -2 0
ELIF (<BASEID> == i_multi_ship_small_s) || (<BASEID> == i_multi_ship_dragon_small_s)
	TRY VAR.<UID>HATCH 0 4 0
	TRY VAR.<UID>TILLERMAN 0 -4 0
	TRY VAR.<UID>LEFTSIDE 2 0 0
	TRY VAR.<UID>RIGHTSIDE -2 0 0
ELIF (<BASEID> == i_multi_ship_small_e) || (<BASEID> == i_multi_ship_dragon_small_e)
	TRY VAR.<UID>HATCH 4 0 0
	TRY VAR.<UID>TILLERMAN -4 0 0
	TRY VAR.<UID>LEFTSIDE 0 -2 0
	TRY VAR.<UID>RIGHTSIDE 0 2 0
// Medium Ships
ELIF (<BASEID> == i_multi_ship_medium_n) || (<BASEID> == i_multi_ship_dragon_medium_n)
	TRY VAR.<UID>HATCH 0 -4 0
	TRY VAR.<UID>TILLERMAN 1 5 0
	TRY VAR.<UID>LEFTSIDE -2 0 0
	TRY VAR.<UID>RIGHTSIDE 2 0 0
ELIF (<BASEID> == i_multi_ship_medium_w) || (<BASEID> == i_multi_ship_dragon_medium_w)
	TRY VAR.<UID>HATCH -4 0 0
	TRY VAR.<UID>TILLERMAN 5 0 0
	TRY VAR.<UID>LEFTSIDE 0 2 0
	TRY VAR.<UID>RIGHTSIDE 0 -2 0
ELIF (<BASEID> == i_multi_ship_medium_s) || (<BASEID> == i_multi_ship_dragon_medium_s)
	TRY VAR.<UID>HATCH 0 4 0
	TRY VAR.<UID>TILLERMAN 0 -5 0
	TRY VAR.<UID>LEFTSIDE 2 0 0
	TRY VAR.<UID>RIGHTSIDE -2 0 0
ELIF (<BASEID> == i_multi_ship_medium_e) || (<BASEID> == i_multi_ship_dragon_medium_e)
	TRY VAR.<UID>HATCH 4 0 0
	TRY VAR.<UID>TILLERMAN -5 0 0
	TRY VAR.<UID>LEFTSIDE 0 -2 0
	TRY VAR.<UID>RIGHTSIDE 0 2 0
// Long Ships
ELIF (<BASEID> == i_multi_ship_long_n) || (<BASEID> == i_multi_ship_dragon_long_n)
	TRY VAR.<UID>HATCH 0 -5 0
	TRY VAR.<UID>TILLERMAN 1 5 0
	TRY VAR.<UID>LEFTSIDE -2 -1 0
	TRY VAR.<UID>RIGHTSIDE 2 -1 0
ELIF (<BASEID> == i_multi_ship_long_w) || (<BASEID> == i_multi_ship_dragon_long_w)
	TRY VAR.<UID>HATCH -5 0 0
	TRY VAR.<UID>TILLERMAN 5 0 0
	TRY VAR.<UID>LEFTSIDE -1 2 0
	TRY VAR.<UID>RIGHTSIDE -1 -2 0
ELIF (<BASEID> == i_multi_ship_long_s) || (<BASEID> == i_multi_ship_dragon_long_s)
	TRY VAR.<UID>HATCH 0 5 0
	TRY VAR.<UID>TILLERMAN 0 -5 0
	TRY VAR.<UID>LEFTSIDE 2 1 0
	TRY VAR.<UID>RIGHTSIDE -2 1 0
ELIF (<BASEID> == i_multi_ship_long_e) || (<BASEID> == i_multi_ship_dragon_long_e)
	TRY VAR.<UID>HATCH 5 0 0
	TRY VAR.<UID>TILLERMAN -5 0 0
	TRY VAR.<UID>LEFTSIDE 1 -2 0
	TRY VAR.<UID>RIGHTSIDE 1 2 0
ENDIF

SRC.NEWITEM=i_nuke_node
SRC.ACT.P=<P>
SRC.ACT.MOVE nw 10
SRC.NUKE shipfix1 <UID>
SRC.LAST
SRC.ACT.MOVE se 20
SRC.LAST

IF (<EVAL HIDENUKETOGGLE> == 1)
	SRC.HIDENUKE 0
ENDIF

[FUNCTION shipfix1]
IF (<UID> != <ARGN>) && (<LINK.UID> == <ARGN>)
	IF (<TYPE> == t_ship_side) || (<TYPE> == t_ship_side_locked) || (<TYPE> == t_ship_plank) || (<TYPE> == t_ship_tiller) || (<TYPE> == t_ship_hold_lock) || (<TYPE> == t_ship_hold)
		IF (<TYPE> == t_ship_hold) || (<TYPE> == t_ship_hold_lock)
			LINK.MOREX=<UID> //Makes docking possible
			IF (<LINK.MORE2> == 00)	|| (<LINK.MORE2> == 01) || (<LINK.MORE2> == 02)				// N
				DISPID 03eae
			ELIF (<LINK.MORE2> == 02020000)	|| (<LINK.MORE2> == 02020001) || (<LINK.MORE2> == 02020002)	// E
				DISPID i_ship_hatch_e
			ELIF (<LINK.MORE2> == 04040000)	|| (<LINK.MORE2> == 04040001) || (<LINK.MORE2> == 04040002)	// S
				DISPID 03eb9
			ELIF (<LINK.MORE2> == 06060000)	|| (<LINK.MORE2> == 06060001) || (<LINK.MORE2> == 06060002)	// W
				DISPID 03e93
			ENDIF
			P=<LINK.P>
			MOVE <VAR.<LINK.UID>HATCH>
		ELIF (<TYPE> == t_ship_tiller)
			IF (<LINK.MORE2> == 00)	|| (<LINK.MORE2> == 01) || (<LINK.MORE2> == 02)				// N
				DISPID 03e4e
			ELIF (<LINK.MORE2> == 02020000)	|| (<LINK.MORE2> == 02020001) || (<LINK.MORE2> == 02020002)	// E
				DISPID 03e55
			ELIF (<LINK.MORE2> == 04040000)	|| (<LINK.MORE2> == 04040001) || (<LINK.MORE2> == 04040002)	// S
				DISPID 03e4b
			ELIF (<LINK.MORE2> == 06060000)	|| (<LINK.MORE2> == 06060001) || (<LINK.MORE2> == 06060002)	// W
				DISPID 03e50
			ENDIF
			P=<LINK.P>
			MOVE <VAR.<LINK.UID>TILLERMAN>
		ELSE
			IF (<LINK.MORE2> == 00)	|| (<LINK.MORE2> == 01) || (<LINK.MORE2> == 02)				// N
				IF (<P.X> > <LINK.P.X>)
					SRC.NEWITEM 03eb2
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>RIGHTSIDE>
				ELIF (<P.X> < <LINK.P.X>)
					SRC.NEWITEM 03eb1
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>LEFTSIDE>
				ENDIF
				shipfix2
			ELIF (<LINK.MORE2> == 02020000)	|| (<LINK.MORE2> == 02020001) || (<LINK.MORE2> == 02020002)	// E
				IF (<P.Y> > <LINK.P.Y>)
					SRC.NEWITEM 03e85
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>RIGHTSIDE>
				ELIF (<P.Y> < <LINK.P.Y>)
					SRC.NEWITEM i_ship_plank_n_c
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>LEFTSIDE>
				ENDIF
				shipfix2
			ELIF (<LINK.MORE2> == 04040000)	|| (<LINK.MORE2> == 04040001) || (<LINK.MORE2> == 04040002)	// S
				IF (<P.X> < <LINK.P.X>)
					SRC.NEWITEM 03eb1
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>RIGHTSIDE>
				ELIF (<P.X> > <LINK.P.X>)
					SRC.NEWITEM 03eb2
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>LEFTSIDE>
				ENDIF
				shipfix2
			ELIF (<LINK.MORE2> == 06060000)	|| (<LINK.MORE2> == 06060001) || (<LINK.MORE2> == 06060002)	// W
				IF (<P.Y> < <LINK.P.Y>)
					SRC.NEWITEM i_ship_plank_n_c
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>RIGHTSIDE>
				ELIF (<P.Y> > <LINK.P.Y>)
					SRC.NEWITEM 03e85
					SRC.ACT.P <LINK.P>
					SRC.ACT.MOVE <VAR.<LINK.UID>LEFTSIDE>
				ENDIF
				shipfix2
			ENDIF
		ENDIF
	ENDIF
	UPDATE
ENDIF

[FUNCTION shipfix2]
SRC.ACT.MORE1=<MORE1>
SRC.ACT.MORE2=<MORE2>
SRC.ACT.ATTR=<ATTR>
SRC.ACT.LINK=<LINK>
IF (<TYPE> == t_ship_plank)
	SRC.ACT.TYPE=t_ship_side
	SRC.ACT.DCLICK
ELSE
	SRC.ACT.TYPE=<TYPE>
ENDIF
REMOVE

[SPEECH spk_ship_cmds]

ON=Set name *
// Changes Ship's name, where *=name.
// NAME=<strmid(<args>,8,64)>

ON=Full speed
IF (<EVAL <TAG.HASTEUID>> > 0)
	VAR.OLDACT=<SRC.ACT.UID>
	SRC.ACT=<EVAL <TAG.HASTEUID>>
	SRC.ACT.TAG.TIMERCOUNT=0
	SRC.ACT=<EVAL <VAR.OLDACT>>
	VAR.OLDACT=
ELSE
	LINK.SAY We're not moving yet, Captain.
ENDIF

ON=Slower
IF (<EVAL <TAG.HASTEUID>> > 0)
	VAR.OLDACT=<SRC.ACT.UID>
	SRC.ACT=<EVAL <TAG.HASTEUID>>
	SRC.ACT.TAG.TIMERCOUNT=<EVAL <SRC.ACT.TAG.TIMERCOUNT> + 1>
	LINK.SAY Ye landlubbers... always wantin' to slow down the boat. So be it. (<EVAL <SRC.ACT.TAG.TIMERCOUNT>>)
	SRC.ACT=<EVAL <VAR.OLDACT>>
	VAR.OLDACT=
ELSE
	LINK.SAY We're not moving yet, Captain.
ENDIF

ON=Faster
IF (<EVAL <TAG.HASTEUID>> > 0)
	VAR.OLDACT=<SRC.ACT.UID>
	SRC.ACT=<EVAL <TAG.HASTEUID>>
	IF (<EVAL <SRC.ACT.TAG.TIMERCOUNT> +(-1)> < <EVAL <SRC.ACT.TAG.MAXTIMERCOUNT>>)
		LINK.SAY We're already goin' full speed, Cap'n.
	ELSE
		SRC.ACT.TAG.TIMERCOUNT=<EVAL <SRC.ACT.TAG.TIMERCOUNT> + (-1)>
		LINK.SAY Aye aye, Cap'n! (<EVAL <SRC.ACT.TAG.TIMERCOUNT>>)
	ENDIF
	SRC.ACT=<EVAL <VAR.OLDACT>>
	VAR.OLDACT=
ELSE
	LINK.SAY We're not moving yet, Captain.
ENDIF

ON=Furl sail	// Stop
ON=Stop			// Stops current ship movement.
	SHIPSTOP

ON=Turn Left
ON=Port			// Turn Left
	SHIPTURNLEFT
	SHIPFIX

ON=Turn Right
ON=Starboard	// Turn Right
	SHIPTURNRIGHT
	SHIPFIX

ON=Left			// Move ship in desired direction.
ON=Drift Left
	SHIPDRIFTLEFT

ON=Right		// Move ship in desired direction.
ON=Drift Right
	SHIPDRIFTRIGHT

ON=Back			// Move ship backwards
ON=Backward		// Move ship backwards
ON=Backwards	// Move ship backwards
	SHIPBACK

ON=Forward
ON=Foreward		// Moves ship forward.
ON=Unfurl sail	// Moves ship forward.
	IF (<eval <TAG.HASTEUID>> == 0)
	SRC.NEWITEM i_shiphaste
	TAG.HASTEUID=<SRC.ACT.UID>
	SRC.ACT.LINK=<UID>
	SRC.ACT.MORE1=<SRC.UID>
	SRC.ACT.NAME=Ship Speed Control for <NAME>
	SRC.ACT.ATTR=attr_invis|attr_move_never
	SRC.ACT.P=<P>
	SRC.ACT.TIMER=1
	ENDIF
	SHIPFORE

ON=Forward left
	SHIPFORELEFT

ON=forward right
	SHIPFORERIGHT

ON=backward left
ON=back left
	SHIPBACKLEFT

ON=backward right
ON=back right
	SHIPBACKRIGHT

ON=Raise Anchor
	SHIPANCHORRAISE

ON=Drop Anchor
	SHIPANCHORDROP

ON=Turn around	// Turns ship around and proceeds.
ON=Come about	// Turns ship around and proceeds.
	SHIPTURN
	SHIPFIX

ON=Up
	SHIPUP

ON=Down
	SHIPDOWN

ON=Land
	SHIPLAND