[ITEMDEF i_multi_ferry_n]
// Face N
DEFNAME=i_multi_ferry_n
ID=i_multi_ship_long_n
Name=Ferry
TYPE=T_ship
VALUE=75000
CATEGORY=Multis
SUBSECTION=Ships
DESCRIPTION=Ferry
MULTIREGION=-2,-7,2,7
COMPONENT=03e4e,1, 5, 0
COMPONENT=i_ship_hatch_n,0,-5, 0
COMPONENT=03eb2,2, -1, 0
COMPONENT=03eb1,-2, -1, 0
TSPEECH spk_ferry

[ITEMDEF i_multi_ferry_e]
// Face E
DEFNAME=i_multi_ferry_e
ID=i_multi_ship_long_e
Name=Ferry
TYPE=T_SHIP
VALUE=75000
CATEGORY=Multis
SUBSECTION=Ships
DESCRIPTION=Ferry
MULTIREGION=-7,-2,7,2
COMPONENT=03e55,-5,0, 0
COMPONENT=i_ship_hatch_e,5, 0, 0
COMPONENT=03e85,1, 2, 0
COMPONENT=03e8a,1,-2, 0
TSPEECH spk_ferry

[ITEMDEF i_multi_ferry_s]
// Face S
DEFNAME=i_multi_ferry_s
ID=i_multi_ship_long_s
Name=Ferry
TYPE=T_SHIP
VALUE=75000
CATEGORY=Multis
SUBSECTION=Ships
DESCRIPTION=Ferry
MULTIREGION=-2,-7,2,5
COMPONENT=03e4b,0, -5,0
COMPONENT=i_ship_hatch_s,0, 5,0
COMPONENT=03eb2,2, 1,0
COMPONENT=03eb1,-2, 1,0
TSPEECH spk_ferry

[ITEMDEF i_multi_ferry_w]
// Face W
DEFNAME=i_multi_ferry_w
ID=i_multi_ship_long_w
Name=Ferry
TYPE=T_SHIP
VALUE=75000
CATEGORY=Multis
SUBSECTION=Ships
DESCRIPTION=Ferry
MULTIREGION=-7,-2,7,2
COMPONENT=03e50,5, 0,0
COMPONENT=i_ship_hatch_w,-5,0,0
COMPONENT=03e85,-1, 2,0
COMPONENT=03e8a,-1,-2,0
TSPEECH spk_ferry

[SPEECH spk_ferry]
ON=What*
ON=*Name*
ON=*Called*
ON=*Refer*
LINK.SAY The ship you stand upon is the fair <NAME>.

ON=*Destination*
ON=*Route*
ON=*Journey*
ON=Where*
IF ((<MOREX>==0)&&(<MOREY>==0))
	LINK.SAY This ferry's out of service until the harbormaster gives us a destination.
ELSE
	VAR.OLDP=<P>
	P=<MOREP>
	LINK.SAY This ferry is bound for <REGION.NAME>. We make round trips. Just tell me to "embark" when you're ready to leave.
	P=<VAR.OLDP>
	VAR.OLDP=
ENDIF

ON=*How much*
ON=*Gold*
ON=*Cost*
ON=*Price*
ON=*Payment*
ON=*Free*
LINK.SAY This ferry's free. Funded by the town, it is.

ON=*Hello*
ON=*Greetings*
ON=*Good day*
ON=*Hail*
ON=*Well met*
VAR.OLDP=<P>
P=<MOREP>
LINK.SAY Well met. This here be a ferry to <REGION.NAME>. Let me know when you're ready to "embark".
P=<VAR.OLDP>
VAR.OLDP=

ON=*How
ON=*Move*
ON=*Set sail*
ON=Go
LINK.SAY Tell me to "embark" when you're ready to leave.

ON=*Stop*
ON=*Turn*
ON=*Left*
ON=*Right*
LINK.SAY This is a ferry! There be no deviating from the route!

ON=Forward
ON=Foreward		// Moves ship forward.
ON=Unfurl sail		// Moves ship forward.
ON=Back			// Move ship backwards
ON=Backward		// Move ship backwards
ON=Backwards		// Move ship backwards
ON=Embark
	FERRYEMBARK

[FUNCTION FERRYEMBARK]
IF ((<MOREX>==0)&&(<MOREY>==0))
	LINK.SAY We can't be going until the harbormaster sets a destination.
	RETURN 1
ENDIF

//Mark the original origin and destinations, if calls interrupt us at sea (possible).
IF (<EVAL <TAG.ORIGIN>> == 0)
	TAG.ORIGIN=<P>
	TAG.ORIGINX=<P.X>
	TAG.ORIGINY=<P.Y>
ENDIF

IF (<EVAL <TAG.DESTINATION>> == 0)
	TAG.DESTINATION=<MOREP>
ENDIF

ATTR=<ATTR>|020

IF (<eval <TAG.FERRYCONTROL>> == 0)
	IF (<EVAL 0<TAG.YALT>> > 0)
		TAG.YFIRST=<EVAL !0<TAG.YFIRST>>
	ENDIF

	SRC.NEWITEM i_ferry_control
	TAG.FERRYCONTROL=<SRC.ACT.UID>
	SRC.ACT.LINK=<UID>
	SRC.ACT.MORE1=<SRC.UID>
	SRC.ACT.NAME=Ferry Control for <NAME>
	SRC.ACT.ATTR=attr_invis|attr_move_never
	SRC.ACT.P=<P>
	SRC.ACT.MOREP=<P>
	SRC.ACT.TIMERd=1
ENDIF

[ITEMDEF i_ferry_control]
ID=i_worldgem_bit
TYPE=t_eq_script
NAME=Ferry Control

ON=@Create
ATTR=attr_invis|attr_move_never

ON=@Timer
IF ((<LINK.ATTR> & 04)&&(<LINK.MOREZ> > <Z>))
	NUDGEUP
	LINK.NUDGEUP
	LINK.REGION.ALLCLIENTS NUDGEUP
	LINK.LINK.NUDGEUP
	VAR.OLDLINK=<LINK.LINK.UID>
	LINK.LINK=<LINK.TAG.HOLD>
	LINK.LINK.NUDGEUP
	LINK.LINK=<LINK.TAG.DOOR1>
	LINK.LINK.NUDGEUP
	LINK.LINK=<LINK.TAG.DOOR2>
	LINK.LINK.NUDGEUP
	LINK.LINK=<VAR.OLDLINK>
	VAR.OLDLINK=
ELSEIF (<EVAL 0<LINK.TAG.YFIRST>> > 0)
	IF (<LINK.MOREY> < <P.Y>)
		LINK.MORE2=01
	ELSEIF (<LINK.MOREY> > <P.Y>)
		LINK.MORE2=040001
	ELSEIF (<LINK.MOREX> < <P.X>)
		LINK.MORE2=060001
	ELSEIF (<LINK.MOREX> > <P.X>)
		LINK.MORE2=020001
	ENDIF
ELSE
	IF (<LINK.MOREX> < <P.X>)
		LINK.MORE2=060001
	ELSEIF (<LINK.MOREX> > <P.X>)
		LINK.MORE2=020001
	ELSEIF (<LINK.MOREY> < <P.Y>)
		LINK.MORE2=01
	ELSEIF (<LINK.MOREY> > <P.Y>)
		LINK.MORE2=040001
	ENDIF
ENDIF

IF ((<LINK.MOREX> == <P.X>)&&(<LINK.MOREY> == <P.Y>))
	LINK.MORE2=0
	IF ((<LINK.ATTR> & 04)&&(<LINK.MOREZ> < <Z>))
		NUDGEDOWN
		LINK.NUDGEDOWN
		LINK.REGION.ALLCLIENTS NUDGEDOWN
		LINK.LINK.NUDGEDOWN
		VAR.OLDLINK=<LINK.LINK.UID>
		LINK.LINK=<LINK.TAG.HOLD>
		LINK.LINK.NUDGEDOWN
		LINK.LINK=<LINK.TAG.DOOR1>
		LINK.LINK.NUDGEDOWN
		LINK.LINK=<LINK.TAG.DOOR2>
		LINK.LINK.NUDGEDOWN
		LINK.LINK=<VAR.OLDLINK>
		VAR.OLDLINK=
	ELSE
		MOVE w 15
		LINK.LINK.SAY We've arrived at our destination, <REGION.NAME>!
		P=<MOREP>
		LINK.LINK.SAY 'Embark' again for a round trip to <REGION.NAME>.
		P=<LINK.P>
		LINK.TAG.FERRYCONTROL=
		LINK.MOREP=<MOREP>
		REMOVE
		RETURN 1
	ENDIF
ENDIF

VAR.CLIENTCOUNT=0
REGION.ALLCLIENTS countclients
IF (<EVAL <VAR.CLIENTCOUNT>> == 0)
	//0 clients screws the speed up.
	VAR.CLIENTCOUNT=1
ENDIF

TAG.MAXTIMERCOUNT=<EVAL <EVAL <VAR.CLIENTCOUNT> / 3> + 1>

IF (<EVAL <TAG.TIMERCOUNT>> < <EVAL <TAG.MAXTIMERCOUNT>>)
	TAG.TIMERCOUNT=<EVAL <TAG.MAXTIMERCOUNT>>
	LINK.LINK.SAY Full speed ahead! (<EVAL <TAG.TIMERCOUNT>>).
ENDIF

TIMERd=<EVAL <TAG.TIMERCOUNT> + 1>
LINK.TIMERd=<EVAL <TAG.TIMERCOUNT>>

RETURN 1

[ITEMDEF i_deed_ferry_n]
DEFNAME=i_deed_ferry_n
ID=i_deed_ship
NAME=Deed to a Ferry
RESOURCES=i_deed,i_multi_ship_long_N

CATEGORY=Provisions - Deeds
SUBSECTION=Ship Plans
DESCRIPTION=Long Ship

VALUE=75000

ON=@Create
MORE=i_multi_ferry_N

ON=@Targon_Ground
SRC.SYSMESSAGE Don't forget to set the ferry's destination!
RETURN 0

[ITEMDEF i_deed_ferry_s]
DEFNAME=i_deed_ferry_s
ID=i_deed_ship
NAME=Deed to a Ferry
RESOURCES=i_deed,i_multi_ship_long_s

CATEGORY=Provisions - Deeds
SUBSECTION=Ship Plans
DESCRIPTION=Long Ship

VALUE=75000

ON=@Create
MORE=i_multi_ferry_s

ON=@Targon_Ground
SRC.SYSMESSAGE Don't forget to set the ferry's destination!
RETURN 0

[ITEMDEF i_deed_ferry_e]
DEFNAME=i_deed_ferry_e
ID=i_deed_ship
NAME=Deed to a Ferry
RESOURCES=i_deed,i_multi_ship_long_e

CATEGORY=Provisions - Deeds
SUBSECTION=Ship Plans
DESCRIPTION=Long Ship

VALUE=75000

ON=@Create
MORE=i_multi_ferry_e

ON=@Targon_Ground
SRC.SYSMESSAGE Don't forget to set the ferry's destination!
RETURN 0

[ITEMDEF i_deed_ferry_w]
DEFNAME=i_deed_ferry_w
ID=i_deed_ship
NAME=Deed to a Ferry
RESOURCES=i_deed,i_multi_ship_long_w

CATEGORY=Provisions - Deeds
SUBSECTION=Ship Plans
DESCRIPTION=Long Ship

VALUE=75000

ON=@Create
MORE=i_multi_ferry_w

ON=@Targon_Ground
SRC.SYSMESSAGE Don't forget to set the ferry's destination!
RETURN 0

[ITEMDEF i_ferry_bell]
ID=01c12
NAME=Ferry Bell
TYPE=t_normal

ON=@Create
ATTR=attr_move_never
MOREP=<P>

ON=@DClick
LINK=<MORE1>
IF (!<LINK.ISITEM>)
	SRC.SYSMESSAGE This bell was never assigned to a ferry. Please contact the harbormaster.
	LINK=0
	RETURN 1
ENDIF

IF ((<LINK.P.X> == <MOREX>)&&(<LINK.P.Y>==<MOREY>))
	SRC.SYSMESSAGE The ferry is already here.
	LINK=0
	RETURN 1
ENDIF

IF ((<LINK.MOREX>==<MOREX>)&&(<LINK.MOREY>==<MOREY>)&&(!<LINK.MORE2> == 0))
	SRC.SYSMESSAGE Patience... it's on its way.
	LINK=0
	RETURN 1
ENDIF

VAR.CLIENTCOUNT=0
LINK.REGION.ALLCLIENTS countclients
IF (<EVAL <VAR.CLIENTCOUNT>> > 0)
	SRC.SYSMESSAGE There are currently passengers on the ferry. Please wait until they disembark.
	VAR.CLIENTCOUNT=
	LINK=0
	RETURN 1
ENDIF

//Wake the sector up.
VAR.OLDP=<SRC.P>
SRC.P=<LINK.P>
SRC.P=<VAR.OLDP>
VAR.OLDP=

LINK=<LINK.TAG.FERRYCONTROL>
IF (<LINK.ISITEM>)
	LINK.LINK.MOREP=<MOREP>	//The MOREP of this item is our new destination.

	//Tell the ship where to go back when done.
	//If we're going to the origin, return to the destination, and vice versa.
	IF ((<MOREX>==<EVAL <LINK.LINK.TAG.ORIGINX>>)&&(<MOREY>==<EVAL <LINK.LINK.TAG.ORIGINY>>))
		LINK.MOREP=<LINK.LINK.TAG.DESTINATION>
	ELSE
		LINK.MOREP=<LINK.LINK.TAG.ORIGIN>
	ENDIF	
ELSE
	//Tell the ship where to go NOW.
	LINK=<MORE1>
	LINK.MOREP=<MOREP>
	LINK.FERRYEMBARK
ENDIF

LINK=0

SRC.SYSMESSAGE The ferry has been summoned. Please wait.
RETURN 1