[TYPEDEF t_namingstone]
DEFNAME=t_namingstone

ON=@DCLICK
IF (<VAR.USEDBOOK> == 1)
	TARGET Choose an unlocked container you wish to rename
	RETURN 1
ELSE
TARGET Choose something (usually a book) with a name you wish to give to the container
VAR.USEDBOOK=0
RETURN 1
ENDIF

ON=@TARGON_ITEM

IF (<VAR.USEDBOOK> == 0)
	VAR.CONTAINERNAME=<SRC.TARG.NAME>
	VAR.USEDBOOK=1
	SRC.MESSAGE Double click the stone again
	RETURN 1
ENDIF

IF (<SRC.TARG.CONT> == <SRC.FINDLAYER(21).SERIAL>)
	IF (<SRC.TARG.TYPE> == t_container)
		SRC.SYSMESSAGE You rename the container <VAR.CONTAINERNAME>
		SRC.TARG.NAME = <VAR.CONTAINERNAME>
		VAR.USEDBOOK=0
		RETURN 1
	ELSE
		SRC.SYSMESSAGE This item is not an unlocked container
		VAR.USEDBOOK=0
		RETURN 1
	ENDIF
ELSE
VAR.USEDBOOK=0
SRC.SYSMESSAGE The item must be in your pack to rename
RETURN 1
ENDIF
VAR.USEDBOOK=0
RETURN 1

[ITEMDEF i_jailtimer]
DEFNAME=i_jailtimer
ID=i_memory
LAYER=layer_special
TYPE=t_eq_script

ON=@Create
ATTR=attr_invis

ON=@DCLICK
TARGET Who do you wish to jail?
RETURN 1

ON=@TARGON_CHAR
MOREP=<SRC.TARG.P>
SRC.TARG.EQUIP
CONT=<SRC.TARG.SERIAL> //Just in case .equip didn't work
SRC.TARG.JAIL
RETURN 1

ON=@Timer
CONT.SYSMESSAGE Your jail time has been served
CONT.FORGIVE
CONT.GO <MOREP>
REMOVE
RETURN 1

[FUNCTION jailtime]
SRC.NEWITEM i_jailtimer
SRC.TARG.SYSMESSAGE You have been jailed for <ARGN> hours. Please page a GM if you have a question as to why you were jailed.
SRC.ACT.TIMER=(<ARGN>*3600)
SRC.ACT.EQUIP
SRC.ACT.DCLICK

[ITEMDEF i_noisemaker]
ID=i_memory
TYPE=t_eq_script
LAYER=30
NAME=Noisemaker
DEFNAME=i_noisemaker

ON=@Create
ATTR=attr_invis
NAME=Noisemaker
MORE1=366
TIMER=5

ON=@Timer
Timer=5
CONT.SFX <MORE1>
RETURN 1

[ITEMDEF i_magicshield]
DEFNAME=i_magicshield
ID=i_crystal_green_big
NAME=shield

ON=@Create
COLOR=05f
ATTR=attr_newbie

ON=@DClick

IF !(<COLOR>=0482)
IF !(<SRC.SERIAL>==<CONT.CONT.SERIAL>)
SRC.SYSMESSAGE You must have this in your pack to use it
RETURN 1
ENDIF
COLOR=0482
LINK=<CONT.SERIAL>
EMOTE glows a bright silver
DROP
ATTR=014
LINK.CONT.RESEND
LINK.CONT.INVUL 1
TIMER=1
ELSE
CONT=<LINK.SERIAL>
COLOR=05f
LINK.CONT.INVUL 0
LINK=0
EMOTE stops glowing
ATTR=04
CONT.CONT.RESEND
ENDIF

ON=@Timer
IF (<COLOR>=0482)
LINK.CONT.MANA = (<LINK.CONT.MANA> - 2)
IF (<LINK.CONT.MANA> < 2)
LINK.CONT.INVUL 0
TRIGGER @DClick
RETURN 1
ELSE
TIMER=1
RETURN 1
ENDIF
ELSE
LINK.INVUL 0
RETURN 1
ENDIF

[ITEMDEF i_lockstat_str]
ID=01ea7
TYPE=t_eq_script
LAYER=30
NAME=Strength Lock

ON=@Create
MOREX=0
MORE1=288
MORE2=0
ATTR=attr_invis|attr_move_never
TIMER=5*60

ON=@Timer

IF !(<LINK>)
REMOVE
ENDIF

LINK.STR=<MORE2>
MORE1=<MORE1>-1
TIMER=5*60

IF (<MORE1>=1)
LINK.SYSMESSAGE Your strength is no longer locked.
REMOVE
ENDIF

RETURN 1

[ITEMDEF i_lockstat_dex]
ID=01ea7
TYPE=t_eq_script
LAYER=30
NAME=Dexterity Lock

ON=@Create
MOREX=0
MORE1=288
MORE2=0
ATTR=attr_invis|attr_move_never
TIMER=5*60

ON=@Timer

IF !(<LINK>)
REMOVE
ENDIF

LINK.DEX=<MORE2>
MORE1=<MORE1>-1
TIMER=5*60

IF (<MORE1>=1)
LINK.SYSMESSAGE Your dexterity is no longer locked.
REMOVE
ENDIF

RETURN 1

[ITEMDEF i_lockstat_int]
ID=01ea7
TYPE=t_eq_script
LAYER=30
NAME=Intelligence Lock

ON=@Create
MOREX=0
MORE1=288
MORE2=0
ATTR=attr_invis|attr_move_never
TIMER=5*60

ON=@Timer

IF !(<LINK>)
REMOVE
ENDIF

LINK.INT=<MORE2>
MORE1=<MORE1>-1
TIMER=5*60

IF (<MORE1>=1)
LINK.SYSMESSAGE Your intelligence is no longer locked.
REMOVE
ENDIF

RETURN 1

[ITEMDEF i_crystal_rprater]
ID=i_crystal_green_big
TYPE=t_eq_script
NAME=Roleplay Crystal

ON=@Create
COLOR=065
ATTR=attr_move_never|attr_invis|attr_blessed2
TIMER=60

ON=@Timer
VAR.RPAVG=0
VAR.RPCLIENTS=0
SERV.ALLCLIENTS EVALRP
IF (<eval <VAR.RPCLIENTS>> > 0)
VAR.RPAVG=<eval <VAR.RPAVG> / <eval <VAR.RPCLIENTS>>>
ELSE
VAR.RPAVG=0
ENDIF

IF (<eval <VAR.RPAVG>> < -9999)
VAR.SERVRP=Is Absolutely Pathetic (-5)
ELSEIF (<eval <VAR.RPAVG>> < -7999)
VAR.SERVRP=Is Horrible (-4)
ELSEIF (<eval <VAR.RPAVG>> < -5999)
VAR.SERVRP=Is Quite Poor (-3)
ELSEIF (<eval <VAR.RPAVG>> < -3999)
VAR.SERVRP=Is Poor (-2)
ELSEIF (<eval <VAR.RPAVG>> < -1999)
VAR.SERVRP=Could use some work (-1)
ELSEIF (<eval <VAR.RPAVG>> < 0)
VAR.SERVRP=Is Average (0)
ELSEIF (<eval <VAR.RPAVG>> == 0)
VAR.SERVRP=Is Unrated (Unrated)
ELSEIF (<eval <VAR.RPAVG>> < 1000)
VAR.SERVRP=Is Average (1)
ELSEIF (<eval <VAR.RPAVG>> < 2500)
VAR.SERVRP=Is Above Average (2)
ELSEIF (<eval <VAR.RPAVG>> < 4000)
VAR.SERVRP=Is Good (3)
ELSEIF (<eval <VAR.RPAVG>> < 6000)
VAR.SERVRP=Is Great (4)
ELSEIF (<eval <VAR.RPAVG>> < 8000)
VAR.SERVRP=Is Excellent (5)
ELSEIF (<eval <VAR.RPAVG>> < 10000)
VAR.SERVRP=Is Superior (6)
ELSEIF (<eval <VAR.RPAVG>> > 9999)
VAR.SERVRP=Is Absolutely Outstanding (7+)
ENDIF

TIMER=60
RETURN 1

[FUNCTION EVALRP]
IF (<eval <TAG.RPRATING>> < -9999)
TAG.MYRP=Is Absolutely Pathetic (-5)
ELSEIF (<eval <TAG.RPRATING>> < -7999)
TAG.MYRP=Is Horrible (-4)
ELSEIF (<eval <TAG.RPRATING>> < -5999)
TAG.MYRP=Is Quite Poor (-3)
ELSEIF (<eval <TAG.RPRATING>> < -3999)
TAG.MYRP=Is Poor (-2)
ELSEIF (<eval <TAG.RPRATING>> < -1999)
TAG.MYRP=Could use some work (-1)
ELSEIF (<eval <TAG.RPRATING>> < 0)
TAG.MYRP=Is Average (0)
ELSEIF (<eval <TAG.RPRATING>> == 0)
TAG.MYRP=Is Unrated (Unrated)
ELSEIF (<eval <TAG.RPRATING>> < 1000)
TAG.MYRP=Is Average (1)
ELSEIF (<eval <TAG.RPRATING>> < 2500)
TAG.MYRP=Is Above Average (2)
ELSEIF (<eval <TAG.RPRATING>> < 4000)
TAG.MYRP=Is Good (3)
ELSEIF (<eval <TAG.RPRATING>> < 6000)
TAG.MYRP=Is Great (4)
ELSEIF (<eval <TAG.RPRATING>> < 8000)
TAG.MYRP=Is Excellent (5)
ELSEIF (<eval <TAG.RPRATING>> < 10000)
TAG.MYRP=Is Superior (6)
ELSEIF (<eval <TAG.RPRATING>> > 9999)
TAG.MYRP=Is Absolutely Outstanding (7+)
ENDIF

IF (<eval <TAG.RPRATING>> != 0)
VAR.RPAVG=<eval <VAR.RPAVG> + <eval <TAG.RPRATING>>>
VAR.RPCLIENTS=<eval <VAR.RPCLIENTS> + 1>
ENDIF

[ITEMDEF i_crystal_weather]
ID=i_crystal_green_big
TYPE=t_eq_script
NAME=Season Crystal

ON=@Create
ATTR=attr_move_never|attr_invis|attr_blessed2
TIMER=1

ON=@Timer
IF (<EVAL <TAG.SEASON>> = 0)
COLOR=026
TAG.SEASONNAME=Summer
NAME=Season Crystal (Summer)
SERV.ALLCLIENTS SYSMESSAGE It grows uncomfortably hot. It is summer.
TAG.SEASON=1
ELSEIF (<EVAL <TAG.SEASON>> = 1)
COLOR=030
TAG.SEASONNAME=Autumn
NAME=Season Crystal (Autumn)
TAG.SEASON=2
SERV.ALLCLIENTS SYSMESSAGE Leaves begin to fall from the trees, turning every color of the rainbow. It is autumn.
ELSEIF (<EVAL <TAG.SEASON>> = 2)
TAG.SEASON=3
COLOR=0481
TAG.SEASONNAME=Winter
NAME=Season Crystal (Winter)
SERV.ALLCLIENTS SYSMESSAGE Snow begins falling and a blanket soon covers the earth. It is winter.
ELSE
TAG.SEASON=0
COLOR=0
SERV.ALLCLIENTS SYSMESSAGE Birds are chirping and flowers are blooming... Spring is here!
TAG.SEASONNAME=Spring
NAME=Season Crystal (Spring)
SERV.ALLCLIENTS SFX <EVAL {01 05}>
ENDIF

MOREP=<P>
P=1,1
REGION.SECTORS SEASON <EVAL <TAG.SEASON>>
P=<MOREP>

TIMER=60*60*24*7
RETURN 1

[ITEMDEF i_linkglow]
ID=01ea7
TYPE=t_eq_script
NAME=Glow item

ON=@Create
ATTR=attr_move_never|attr_invis
MORE1=02 //Starting color
MORE2=04 //Ending color
MOREX=1  //Timerd value
TAG.INCREMENT=1
TIMERd=1

ON=@Timer
IF (<LINK.COLOR> > <eval <MORE1>>)
IF (<LINK.COLOR> < <eval <MORE2>>)
LINK.COLOR=<LINK.COLOR> + <eval <TAG.INCREMENT>>
ELSE
TAG.INCREMENT=-1
LINK.COLOR=<LINK.COLOR> + <eval <TAG.INCREMENT>>
ENDIF
ELSE
TAG.INCREMENT=1
LINK.COLOR=<LINK.COLOR> + <eval <TAG.INCREMENT>>
ENDIF

TIMERd=<MOREX>
RETURN 1

[ITEMDEF i_linkfloat]
ID=01ea7
TYPE=t_eq_script
NAME=Float item

ON=@Create
ATTR=attr_move_never|attr_invis
MORE1=5	//Number of Z-levels to float up before returning.
MOREX=0
MOREY=0
MOREZ=2
TIMERd=2

ON=@Timer
IF (<MOREX> == 1)
	IF (<MOREY> < <MORE1>)
		MOREY=<EVAL <MOREY> + 1>
		LINK.NUDGEUP 1
	ELSE
		MOREX=0
	ENDIF
ENDIF

IF (<MOREX> == 0)
	IF (<MOREY> > 0)
		MOREY=<EVAL <MOREY> + (-1)>
		LINK.NUDGEDOWN 1
	ELSE
		MOREX=1
		MOREY=1
		LINK.NUDGEUP 1
	ENDIF
ENDIF

TIMERd=<MOREZ>
RETURN 1

[ITEMDEF i_statreset]
ID=i_memory
TYPE=t_eq_script
NAME=Stat fixer for curse/bless
LAYER=30

ON=@Create
ATTR=attr_invis|attr_move_never|attr_decay

ON=@Timer
IF (<CONT.FINDID.i_rune_curse>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_mass_curse>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_feeblemind>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_clumsy>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_weaken>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_bless>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_cunning>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_agility>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_strength>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_rune_polymorph>)
TIMER=60
RETURN 1
ENDIF

IF (<CONT.FINDID.i_newpoly>)
TIMER=60
RETURN 1
ENDIF

IF (<EVAL <TAG.CHARSTR>> > 0)
IF (<EVAL <TAG.CHARSTR>> <= <EVAL <CONT.TAG.STRCAP>>)
CONT.STR=<EVAL <TAG.CHARSTR>>
//CONT.SYSMESSAGE STR <EVAL <TAG.CHARSTR>> (This is a debug message and will disappear soon. Ignore it for now.)
ENDIF
ENDIF

IF (<EVAL <TAG.CHARINT>> > 0)
IF (<EVAL <TAG.CHARINT>> <= <EVAL <CONT.TAG.INTCAP>>)
CONT.INT=<EVAL <TAG.CHARINT>>
//CONT.SYSMESSAGE INT <EVAL <TAG.CHARINT>> (This is a debug message and will disappear soon. Ignore it for now.)
ENDIF
ENDIF

IF (<EVAL <TAG.CHARDEX>> > 0)
IF (<EVAL <TAG.CHARDEX>> <= <EVAL <CONT.TAG.DEXCAP>>)
CONT.DEX=<EVAL <TAG.CHARDEX>>
//CONT.SYSMESSAGE DEX <EVAL <TAG.CHARDEX>> (This is a debug message and will disappear soon. Ignore it for now.)
ENDIF
ENDIF

REMOVE
RETURN 0

[TYPEDEF t_galleryexit]

ON=@DClick
SRC.P=<SRC.TAG.LEFTP>
SRC.TAG.LEFTP=
SRC.RESEND

ON=@Step
SRC.P=<SRC.TAG.LEFTP>
SRC.TAG.LEFTP=
SRC.RESEND